#!/bin/sh
# -*- perl -*-
if [ -d "/opt/.zeus_vault" -o -f "/etc/zxtm-version" ] ; then
    ZEUSHOME=/opt/zeus
    export ZEUSHOME
fi

exec $ZEUSHOME/perl/miniperl -wx $0 ${1+"$@"}
 if 0;
#!/usr/bin/perl -w
#line 12

# Historical Activity graph generator
#
# Copyright (C) Zeus Technology 2006 <support@zeus.com>

BEGIN {
   $ENV{"PATH"} = "$ENV{PATH}:/bin:/usr/bin";
   ($ENV{"ZEUSHOME"}) = ( $ENV{"ZEUSHOME"} =~ m@^(.*)$@ ); # Untaint
   unshift @INC,  "$ENV{ZEUSHOME}/zxtmadmin/lib/perl", "$ENV{ZEUSHOME}/perl";
}


use Zeus::Execute qw( execute );
use Zeus::ZXTM::Statd qw( LineGraph );
use strict;

sub Usage($)
{
   my $fh = shift;

   print $fh <<EOF;
Usage: $0 --output=image.png [OPTIONS]

Generates a graph of historical activity for the ZXTM. If given no
arguments, will default to graphing all virtual servers for 24 hours

Required arguments:

  --output=FILE       File to output image to ('-' for stdout)

Optional arguments:

  --time=HOURS        Number of hours to graph (default 24)
  --width=WIDTH       Width of output graph (default 640)
  --height=HEIGHT     Height of output graph (default 480)
  --allvs             Graph all Virtual Servers (default)
  --allpools          Graph all pools
  --allnodes          Graph all nodes
  --vs=VS1,VS2        Graph a subset of virtual servers
  --pool=POOL1,POOL2  Graph a subset of pools
  --node=NODE1,NODE2  Graph a subset of nodes
  --linear            Graph using a linear axis (default)
  --logarithmic       Graph using a logarithmic axis
  --hits              Graph hits per minute (default)
  --bytes             Graph bytes per second
  --help              Show this help message
EOF
}


my $time = 24;
my $type = 'V';
my $index = 0;
my $objects = undef;
my $axistype = 'linear';
my $w = 640;
my $h = 480;
my $output;

foreach my $arg( @ARGV ) {
   my( $key, $val ) = split /=/, $arg, 2;
   if( $key eq '--help' ) {
      Usage( \*STDOUT );
      exit( 0 );
   } elsif( $key eq "--time" ) {
      $time = $val;
   } elsif( $key eq '--width' ) {
      $w = $val;
   } elsif( $key eq '--height' ) {
      $h = $val;
   } elsif( $key eq '--linear' ) {
      $axistype = 'linear';
   } elsif( $key eq '--logarithmic' ) {
      $axistype = 'logarithmic';
   } elsif( $key eq '--hits' ) {
      $index = 0;
   } elsif( $key eq '--bytes' ) {
      $index = 1;
   } elsif( $key eq '--allvs' ) {
      $type = 'V';
   } elsif( $key eq '--allpools' ) {
      $type = 'P';
   } elsif( $key eq '--allnodes' ) {
      $type = 'N';
   } elsif( $key eq '--vs' ) {
      $type = 'V';
      $objects = [ split ',', $val ];
   } elsif( $key eq '--pool' ) {
      $type = 'P';
      $objects = [ split ',', $val ];
   } elsif( $key eq '--node' ) {
      $type = 'N';
      $objects = [ split ',', $val ];
   } elsif( $key eq '--output' ) {
      $output = $val;

   } else {
      Usage( \*STDERR );
      exit( 1 );
   }
}

if( ! $output ) {
   Usage( \*STDERR );
   exit( 1 );
}

my( $error, $data, $linecolours, $failed )
    = LineGraph( minutes => $time * 60,
                 type => $type,
                 index => $index,
                 objects => $objects,
                 axistype => $axistype,
               );

if( !$error ) {
   my $graph = "$ENV{ZEUSHOME}/zxtmadmin/bin/graph.line";
   my( $exit, $stdout, $stderr ) = execute( "$graph --size ${w}x${h}",
                                            $data );

   if( $exit == 0 ) {
      if( $output eq '-' ) {
         print $stdout;
      } else {
         open FILE, ">$output" or die "Failed to open '$output' for writing: $!\n";
         print FILE $stdout;
         close FILE;
      }

      if( scalar keys %$linecolours ) {
         print STDERR "Line colours:\n\n";
         foreach my $key( keys %$linecolours ) {
            print STDERR "$$linecolours{$key}: $key\n";
         }
      }
      exit ( 0 );
   } else {
      $error = $stderr;
   }
}

$error =~ s/\.\s+/\n/g;
print STDERR "$error\n";
exit 1;